**To Calculate a New Statistic**  
Initial objective:  
1. build a test lo05bias statistic into the model to understand how to integrate new statistics.  
2. up KVARY five times by 0.05 or 0.02 to see how statistic changes when running the model normally (drop the calibration routine so that you change KVARY and then get an output set of statistics).  
3. do the same for AGWR.  
Goal is to understand the calibration factors.  
  
Steps:  
1. Make the following changes in /model/p52/code/src/postproc/river/stats/flowstats.f  
  
\*\*\*\*\*\*\*\* variables for lowest 10% and 5% bias - 5% added by ICPRB  
      real low10obs,low10sim,low10bias,low05obs,low05sim,low05bias  
      integer ord(ndaymax)   
  
\*\*\*\*\*\*\*\*\* calculate biase for low 5% of observed data - added by ICPRB  
      call qsortr(ord,ndays,obs)  ! sort (does not destroy order of obs)  
      low05obs = 0.0  
      low05sim = 0.0  
      do nd = 1,ndays/20  
        low05obs = low05obs + obs(ord(nd))  
        low05sim = low05sim + sim(ord(nd))  
      end do  
      if (low05obs.gt.0) then  
        low05bias = (low05sim-low05obs)/low05obs  
      else  
        low05bias = -9  
      end if  
  
     write(pltfil,\*,err=951) 'low05 bias    ,',low05bias  
  
2. Need to run compile from /model/p52/code/src/postproc/river/stats/ to compile changes to flowstats.f  
  
3. Make the following changes to /model/p52/run/calibration/PWATER/sumall.csh  
  
 grep 'low05 bias   ' $tree/output/river/stats/${scenario}/\*\_${year1}\_${year2}.FLOW > $tree/output/river/summary/$scenario/flow\_lo05.csv  
  
 grep 'low05 bias   ' $tree/output/river/stats/${scenario}/\*\_${year1}\_${year2}.QFLW > $tree/output/river/summary/$scenario/qflw\_lo05.csv  
  
 grep 'low05 bias   ' $tree/output/river/stats/${scenario}/\*\_${year1}\_${year2}.BFLW > $tree/output/river/summary/$scenario/bflw\_lo05.csv  
  
4a. Ross is missing a step: Make following changes to /model/p52/code/src/postproc.postutils/sumstats/sumstats.inc  
  
      include '../../../lib/inc/standard.inc'  
      include '../../../lib/inc/locations.inc'  
  
      integer i   ! index  
      character\*200 longline  
  
      integer maxsites,ns    ! maximum calibration sites  
      parameter (maxsites = 300)  
  
      character\*13 segment(maxsites)  
  
      integer nparms,np     ! number of parameters  
      parameter (nparms=11)  
      character\*4 parname(nparms)  ! names of parameters  
      data parname /'bias','effy','Leff',  
     .              'avri','Meff','Wntr','Sumr',  
     .              'Wari','Sari','lo10','lo05'/  
      integer fnum(nparms)  ! file number  
      data fnum /11,12,13,14,15,16,17,18,19,20,21/  
  
      real values(nparms,maxsites)  
  
\*\*\*\*\*\*\*\*\*\*\* special vars for reading peak files  
      integer npeakparms     ! number of parameters  
      parameter (npeakparms=2)  
      character\*5 peakparname(npeakparms)  ! names of parameters  
      data peakparname /'pbias','vbias'/  
  
      real peakvalues(npeakparms,maxsites)  
  
4b. Make the following changes to /model/p52/code/src/postproc/postutils/sumstats/main.f  
  
      write(dfile,'(a13,17(a1,a8))',err=951)  
     .      'SEGMENT',',','Tbias',',','Wstat',  
     .      ',','Sstat',',','Qstat',',','Bstat',',',  
     .      'Total\_E',',','Total\_LE',',','Mon\_eff',',',  
     .      'QaveRI',',','BaveRI',',','Pbias',',','VPbias',  
     .      ',','WBaveRI',',','SBaveRI',',','lo10bias',',','lo5bias'  
      do ns = 1,numsites(1)  
        do ns2 = 1,numsites(2)  
          if (allsegs(1,ns).eq.allsegs(2,ns2)) then  ! match 1 and 2  
            do ns3 = 1,numsites(3)  
              if (allsegs(1,ns).eq.allsegs(3,ns3)) then ! match 2 and 3  
                do np = 1,numpsites  
                  if (allsegs(1,ns).eq.allpsegs(np)) then ! match 1 & p  
                    Tbias = allvalues(1,1,ns)  
                    Qbias = allvalues(2,1,ns2)  
                    Bbias = allvalues(3,1,ns3)  
                    Wbias = allvalues(1,6,ns)  
                    Sbias = allvalues(1,7,ns)  
                    Qstat = (Qbias+1.0) / (Tbias+1.0)  
                    Bstat = (Bbias+1.0) / (Tbias+1.0)  
                    Wstat = (Wbias+1.0) / (Tbias+1.0)  
                    Sstat = (Sbias+1.0) / (Tbias+1.0)  
              write(dfile,112,err=951) allsegs(1,ns),Tbias,Wstat,Sstat,  
     .        Qstat,Bstat,  
     .        allvalues(1,2,ns),allvalues(1,3,ns),allvalues(1,5,ns),  
     .        allvalues(2,4,ns2),allvalues(3,4,ns3),  
     .        peakvalues(1,np),peakvalues(2,np),  
     .        allvalues(3,8,ns3),allvalues(3,9,ns3),allvalues(1,10,ns),allvalues(1,11,ns)  
                  end if  
                end do  
              end if  
            end do  
          end if  
        end do  
      end do  
      close(dfile)  
  
      stop  
  
112   format(a13,17(', ',f7.3))  
  
***Didn't do anything to makeltype.f or makeptype.f, which are supposed to open csv files.***  
  
5. Make the following changes in the getRstats() subroutine of /model/p52/code/src/calibration\_utils/change\_param/calib\_iter/PWATER/getall.f  
  
\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*  
\*\* subroutine get river calibration stats                             \*\*  
\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*  
      subroutine getRstats(  
     I               rscen,uniqindex,version,R2L,nR2L,nlsegs,rsegs,  
     O               facLandEvap,facLZSN,facINFILT,facIRC,facAGWR,  
     O               facINTFW,facAGWETP,facKVARY)  
      include '../../../../lib/inc/standard.inc'  
      include '../../../../lib/inc/locations.inc'  
      include 'calib.inc'  
      real rdum  
      integer nr  
      character\*(\*) version  
      character\*200 statline  
  
\*\*\*\*\*\*\*\*\*\*\*\* Calibration Parameters  
      real Tbias(maxrsegs),Wstat(maxrsegs),Sstat(maxrsegs)  
      real Qstat(maxrsegs),Bstat(maxrsegs),QaveRI(maxrsegs)  
      real BaveRI(maxrsegs),Pbias(maxrsegs),VPbias(maxrsegs)  
      real WBaveRI(maxrsegs),SBaveRI(maxrsegs),lo10bias(maxrsegs),lo5bias(maxrsegs)  
  
\*\*\*\*\*\*\*\*\*\*\*\*\* functions to calculate factors  
      real calfacLandEvap,calfacLZSN,calfacINFILT,calfacIRC  
      real calfacAGWR,calfacINTFW,calfacAGWETP,calfacKVARY  
      external calfacLandEvap,calfacLZSN,calfacINFILT,calfacIRC  
      external calfacAGWR,calfacINTFW,calfacAGWETP,calfacKVARY  
  
      do nr = 1,maxrsegs    ! set to -9 to test that calib data exists  
        facLandEvap(nr) = -9.0  
      end do  
  
      call lencl(rscen,lenrscen)  
      fnam = outdir//'river/summary/'//rscen(:lenrscen)//  
     .             '\_sum\_stats\_'//version//'.csv'  
      open(dfile+1,file=fnam,status='unknown',iostat=err)  
      if (err.ne.0) go to 991  
      fnam = outdir//'river/summary/'//rscen(:lenrscen)//  
     .             '\_sum\_stats.csv'  
      open(dfile,file=fnam,status='old',iostat=err)  
      if (err.ne.0) go to 991  
  
      read(dfile,'(a200)',end=100,err=992) statline  
      call ryt(statline,dfile+1)  
      do  
        read(dfile,'(a200)',end=100,err=992) statline  
        call ryt(statline,dfile+1)  
        read(statline(5:8),'(i4)',err=992,end=992) nr  
        nr = uniqindex(nr)  
        call shift(statline)  
        read(statline,\*,err=992,end=992)  
     .            Tbias(nr),Wstat(nr),Sstat(nr),Qstat(nr),Bstat(nr),  
     .            rdum,rdum,rdum,  
     .            QaveRI(nr),BaveRI(nr),Pbias(nr),VPbias(nr),  
     .            rdum,rdum,lo10bias(nr),lo5bias(nr)  
  
        facLandEvap(nr) = calfacLandEvap(  
     I                Tbias(nr),Wstat(nr),Sstat(nr),Qstat(nr),Bstat(nr),  
     I                QaveRI(nr),BaveRI(nr),Pbias(nr),VPbias(nr),  
     I                WBaveRI(nr),SBaveRI(nr),lo10bias(nr),lo5bias(nr))  
        facLZSN(nr)     = calfacLZSN(  
     I                Tbias(nr),Wstat(nr),Sstat(nr),Qstat(nr),Bstat(nr),  
     I                QaveRI(nr),BaveRI(nr),Pbias(nr),VPbias(nr),  
     I                WBaveRI(nr),SBaveRI(nr),lo10bias(nr),lo5bias(nr))  
        facINFILT(nr)   = calfacINFILT(  
     I                Tbias(nr),Wstat(nr),Sstat(nr),Qstat(nr),Bstat(nr),  
     I                QaveRI(nr),BaveRI(nr),Pbias(nr),VPbias(nr),  
     I                WBaveRI(nr),SBaveRI(nr),lo10bias(nr),lo5bias(nr))  
        facIRC(nr)      = calfacIRC(  
     I                Tbias(nr),Wstat(nr),Sstat(nr),Qstat(nr),Bstat(nr),  
     I                QaveRI(nr),BaveRI(nr),Pbias(nr),VPbias(nr),  
     I                WBaveRI(nr),SBaveRI(nr),lo10bias(nr),lo5bias(nr))  
        facAGWR(nr)     = calfacAGWR(  
     I                Tbias(nr),Wstat(nr),Sstat(nr),Qstat(nr),Bstat(nr),  
     I                QaveRI(nr),BaveRI(nr),Pbias(nr),VPbias(nr),  
     I                WBaveRI(nr),SBaveRI(nr),lo10bias(nr),lo5bias(nr))  
        facINTFW(nr)    = calfacINTFW(  
     I                Tbias(nr),Wstat(nr),Sstat(nr),Qstat(nr),Bstat(nr),  
     I                QaveRI(nr),BaveRI(nr),Pbias(nr),VPbias(nr),  
     I                WBaveRI(nr),SBaveRI(nr),lo10bias(nr),lo5bias(nr))  
        facAGWETP(nr)   = calfacAGWETP(  
     I                Tbias(nr),Wstat(nr),Sstat(nr),Qstat(nr),Bstat(nr),  
     I                QaveRI(nr),BaveRI(nr),Pbias(nr),VPbias(nr),  
     I                WBaveRI(nr),SBaveRI(nr),lo10bias(nr),lo5bias(nr))  
        facKVARY(nr)    = calfacKVARY(  
     I                Tbias(nr),Wstat(nr),Sstat(nr),Qstat(nr),Bstat(nr),  
     I                QaveRI(nr),BaveRI(nr),Pbias(nr),VPbias(nr),  
     I                WBaveRI(nr),SBaveRI(nr),lo10bias(nr),lo5bias(nr))  
  
      end do  
  
100   close(dfile)  
      close(dfile+1)  
  
\*\*\*\*\*\*\*\*\*\*\*\*\*\* CHECK THAT THE RIVER SEGMENT DATA WERE FOUND  
      do ns = 1,nlsegs  
        do nr = 1,nR2L(ns)  
          if (abs(facLandEvap(R2L(ns,nr))+9.0).lt.0.01) go to 993  
        end do  
      end do  
   
      return  
  
991   report(1) = 'error opening file'  
      report(2) = fnam  
      report(3) = ' '  
      go to 999  
  
992   report(1) = 'error reading file near line'  
      report(2) = fnam  
      report(3) = statline  
      go to 999  
  
993   report(1) = 'did not find segment '//rsegs(R2L(ns,nr))  
      report(2) = ' in file'  
      report(3) = fnam  
      go to 999  
  
999   call stopreport(report)  
      end  
  
6. Make the following /model/p52/config/control/calib/PWATER/p52NL/p52NL\_sensitivities.f  
Red indicates the equations used to modify KVARY and AGWR!!!!  
   
     function calfacLandEvap(Tbias,Wstat,Sstat,Qstat,Bstat,QaveRI,  
     .                        BaveRI,Pbias,VPbias,WBaveRI,SBaveRI,lo10,lo05)  
      implicit none  
      real Tbias,Wstat,Sstat,Qstat,Bstat,QaveRI,BaveRI,  
     .     Pbias,VPbias,WBaveRI,SBaveRI,lo10,lo05,calfacLandEvap  
      calfacLandEvap = 2. / (2. - Tbias)  
      end  
  
      function calfacLZSN(Tbias,Wstat,Sstat,Qstat,Bstat,QaveRI,  
     .                        BaveRI,Pbias,VPbias,WBaveRI,SBaveRI,lo10,lo05)  
      implicit none  
      real Tbias,Wstat,Sstat,Qstat,Bstat,QaveRI,BaveRI,  
     .     Pbias,VPbias,WBaveRI,SBaveRI,lo10,lo05,calfacLZSN  
C      calfacLZSN = ((3.0 - Sstat/Wstat) / 2.0)  
      calfacLZSN = ((2.5 - Sstat/Wstat) / 1.5)  
      end  
  
      function calfacINFILT(Tbias,Wstat,Sstat,Qstat,Bstat,QaveRI,  
     .                        BaveRI,Pbias,VPbias,WBaveRI,SBaveRI,lo10,lo05)  
      implicit none  
      real Tbias,Wstat,Sstat,Qstat,Bstat,QaveRI,BaveRI,  
     .     Pbias,VPbias,WBaveRI,SBaveRI,lo10,lo05,calfacINFILT  
      calfacINFILT = 1.0/Bstat  
      end  
  
      function calfacIRC(Tbias,Wstat,Sstat,Qstat,Bstat,QaveRI,  
     .                        BaveRI,Pbias,VPbias,WBaveRI,SBaveRI,lo10,lo05)  
      implicit none  
      real Tbias,Wstat,Sstat,Qstat,Bstat,QaveRI,BaveRI,  
     .     Pbias,VPbias,WBaveRI,SBaveRI,lo10,lo05,calfacIRC  
      calfacIRC = 2.0 / (1.0 + QaveRI)  
      end  
  
      function calfacAGWR(Tbias,Wstat,Sstat,Qstat,Bstat,QaveRI,  
     .                        BaveRI,Pbias,VPbias,WBaveRI,SBaveRI,lo10,lo05)  
      implicit none  
      real Tbias,Wstat,Sstat,Qstat,Bstat,QaveRI,BaveRI,  
     .     Pbias,VPbias,WBaveRI,SBaveRI,lo10,lo05,calfacAGWR  
      calfacAGWR = 2.0 / (1.0 + BaveRI)  
      end  
  
      function calfacINTFW(Tbias,Wstat,Sstat,Qstat,Bstat,QaveRI,  
     .                        BaveRI,Pbias,VPbias,WBaveRI,SBaveRI,lo10,lo05)  
      implicit none  
      real Tbias,Wstat,Sstat,Qstat,Bstat,QaveRI,BaveRI,  
     .     Pbias,VPbias,WBaveRI,SBaveRI,lo10,lo05,calfacINTFW  
      if (abs(VPbias+9).lt.0.01 .or. abs(Pbias+9.0).lt.0.01) then  
        calfacINTFW = 1.0  
      else  
        if (VPbias\*Pbias.gt.0) then  
          if (abs(Pbias).gt.abs(VPbias)) then  
            calfacINTFW = 1.0 + Pbias / 2.0  
          else  
            calfacINTFW = 1.0 + VPbias / 2.0  
          end if  
        else  
          calfacINTFW = 1.0  
        end if  
      end if  
      end  
  
      function calfacAGWETP(Tbias,Wstat,Sstat,Qstat,Bstat,QaveRI,  
     .                        BaveRI,Pbias,VPbias,WBaveRI,SBaveRI,lo10,lo05)  
      implicit none  
      real Tbias,Wstat,Sstat,Qstat,Bstat,QaveRI,BaveRI,  
     .     Pbias,VPbias,WBaveRI,SBaveRI,lo10,lo05,calfacAGWETP  
C       calfacAGWETP = 1.0 + (Sstat-1.0)\*5.0  
        calfacAGWETP = 1.0 + (Sstat-1.0)\*8.0  
      end  
  
      function calfacKVARY(Tbias,Wstat,Sstat,Qstat,Bstat,QaveRI,  
     .                        BaveRI,Pbias,VPbias,WBaveRI,SBaveRI,lo10,lo05)  
      implicit none  
      real Tbias,Wstat,Sstat,Qstat,Bstat,QaveRI,BaveRI,  
     .     Pbias,VPbias,WBaveRI,SBaveRI,lo10,lo05,calfacKVARY  
      calfacKVARY = 1.0  
      end  
        
Having problems with code changes. The problems were because Fortran cannot read beyond a certain number of characters per line. So I had to go through the code and continue some of the commands on the next line. The other problem had to do with spacing. I had defined lo5 with 3 characters and the program required 4 so it was sticking an extra space in the file path and so wasn't able to open the .csv files. The third problem was because I didn't compile some of the scripts. So I just went through each folder that contained files that I had changed and ran the compile script whenever I found one.